//This file is licensed under the terms of the CC-LGPL

#declare Fast = no;

camera
{ location <8, 9, -10>*3
//  look_at 6.6/2-y*.4
  look_at 3*(y+z)
  angle 35
}

light_source
{ <20, 30, -10>, 1
  fade_distance 30
  fade_power 2
  #if(!Fast)
    area_light x*4, y*4, 16, 16 jitter adaptive 1 circular orient
  #end
}

light_source
{ <-20, 20, -15>, .5
  fade_distance 30
  fade_power 2
  #if(!Fast)
    area_light x*4, y*4, 16, 16 jitter adaptive 1 circular orient
  #end
}

plane
{ y, 0
  #if(Fast)
    pigment { rgb <1, .9, .7> }
  #else
    texture
    { average texture_map
      { #declare S = seed(0);
        #local ReflColor = .8*<1, .9, .7> + .2*<1,1,1>;
        #declare Ind = 0;
        #while(Ind < 20)
          [1 pigment { rgb <1, .9, .7> }
             normal { bumps .1 translate <rand(S),rand(S),rand(S)>*100 scale .001 }
             finish { reflection { ReflColor*.1, ReflColor*.5 } }
          ]
          #declare Ind = Ind+1;
        #end
      }
    }
  #end
}

#include "RM_RubiksMagic.inc"

object
{ RM_RubiksMagic("RUmDmLmRLvUmDm")
  rotate 90*z
  rotate 120*y
  translate RM_HalfThickness*y
  translate RM_HalfSize*y
  translate 4*x + 2*z
}