#version 3.7;                                                                                                                     
//global_settings { assumed_gamma 1.4 }                                                                                           

#declare Fast = yes;

#include "colors.inc"
#include "rm_rubiksmagic.inc"

#declare RM_Decoration = RM_DecMatchbox;     // this is the default decoration
#declare camloc = <0, 9, -0.1>*4;

#declare cfgstring = "RULDLLDU";

#switch (clock)
  #range (-0.5,0.5)  // cuore
    #declare cfgstring = "RULDLLDU";
    #declare mytr = transform {
      rotate 180*z
      translate RM_HalfThickness*y + RM_Size*<+1.0,0,-1.0>
      rotate (90+45)*y
      translate 0.35*RM_Size*z
    }
    #declare camloc = 1.12*camloc;
  #break

  #range (0.5,1.5)  // 2x4
    #declare cfgstring =   "RRRURRRU";
    #declare mytr = transform {translate RM_HalfThickness*y + RM_Size*<-1.5,0,-0.5>}
  #break

  #range (1.5,2.5)  // 2x4 richiede raggera
    #declare cfgstring =   "RRURRRUR";
    #declare mytr = transform {translate RM_HalfThickness*y + RM_Size*<-0.5,0,-0.5>}
  #break

  #range (2.5,3.5)  // 2x4 richiede cingolo
    #declare cfgstring =   "DRRRDRRR";
    #declare mytr = transform {translate RM_HalfThickness*y + RM_Size*<+1.5,0,+0.5>}
  #break

  #range (3.5,4.5)  // 2x4 richiede composita
    #declare cfgstring =   "LLDLLLDL";
    #declare mytr = transform {translate RM_HalfThickness*y + RM_Size*<+0.5,0,+0.5>}
  #break

  #range (4.5,5.5)  // 2x4 richiede finestra
    #declare cfgstring =   "DUDLDUDL";
    #declare mytr = transform {rotate -90*y translate RM_HalfThickness*y + RM_Size*<-1.5,0,-0.5>}
  #break

  #range (5.5,6.5)  // 2x4 black tiles
    #declare cfgstring =   "RRRURRRU";
    #declare mytr = transform {translate RM_HalfThickness*y + RM_Size*<-1.5,0,-0.5>}
    #declare RM_Decoration = RM_DecBlack;
  #break

  #range (6.5,7.5)  // fermata del tram
    #declare cfgstring = "RRmRRmRUmDUm";
    #declare mytr = transform {
      translate RM_Size*<-0.5,1.0,0.0>
      rotate 90*z
      rotate 40*y
      rotate 60*x
    }
    #declare camloc = 0.95*camloc;
  #break
#end
  

/* ========================================================================
 * floor, lights, camera...
 */

//background {White}

object {
  RM_RubiksMagic(cfgstring)
  finish {
    ambient 0.3 diffuse 1
    specular 0.5 roughness 0.05
    //brilliance 1
    phong .75
  }
  transform {mytr}
}
 
camera {
  location camloc
  look_at <0,0,0>
  angle 35
}

light_source
{ 2*<20, 30, -10>, 1
}

light_source
{ 2*<-20, 20, -15>, .5
}